Files
proxmark3/bootrom/ldscript-flash-common
T
iceman1001andClaude Opus 5.5 3515724f9a bootrom: give phase2 .data its own RW segment instead of an RWX one
.data shared the bootphase2 output section with the RAM-executed code, so
the PM5 bootrom linked with "LOAD segment with RWX permissions" (CMake
silenced it with --no-warn-rwx-segments). Put .data in .bootphase2_data
with its own PT_LOAD, placed right after .bootphase2 in RAM and flash so
the existing copy loop still covers it; asserts guard the contiguity.

Same image size on RDV4/PM5/PM5+BWM; code identical bar .ramfunc moving
ahead of .data, data bytes unchanged.

Co-Authored-By: Claude Opus 5.5 <noreply@anthropic.com>
2026-11-10 07:35:47 +07:00

86 lines
2.5 KiB
Plaintext

/*
-----------------------------------------------------------------------------
Copyright (C) Jonathan Westhues, Mar 2006
Copyright (C) Proxmark3 contributors. See AUTHORS.md for details.
This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
See LICENSE.txt for the text of the license.
-----------------------------------------------------------------------------
Bootrom linker script common to all flash-based targets.
-----------------------------------------------------------------------------
*/
PHDRS
{
phase1 PT_LOAD;
phase2 PT_LOAD;
phase2data PT_LOAD;
bss PT_LOAD;
}
ENTRY(flashstart)
SECTIONS
{
.bootphase1 : {
*(.startup)
. = ALIGN(4);
_version_information_start = .;
KEEP(*(.version_information));
. = LENGTH(bootphase1) - 0x4;
LONG(_version_information_start);
} >bootphase1 :phase1
.bootphase2 : {
KEEP(*(.startphase2))
*(.text)
*(.text.*)
*(.eh_frame)
*(.glue_7)
*(.glue_7t)
*(.rodata)
*(.rodata.*)
*(.ramfunc)
. = ALIGN(4);
} >ram AT>bootphase2 :phase2
/* own RW segment, else phase2 is RWX; copied together with .bootphase2 */
.bootphase2_data : {
*(.data)
*(.data.*)
. = ALIGN(4);
} >ram AT>bootphase2 :phase2data
__bootphase2_src_start__ = LOADADDR(.bootphase2);
__bootphase2_start__ = ADDR(.bootphase2);
__bootphase2_end__ = ADDR(.bootphase2_data) + SIZEOF(.bootphase2_data);
ASSERT(ADDR(.bootphase2_data) == __bootphase2_start__ + SIZEOF(.bootphase2), "bootphase2 data not contiguous in RAM")
ASSERT(LOADADDR(.bootphase2_data) == __bootphase2_src_start__ + SIZEOF(.bootphase2), "bootphase2 data not contiguous in flash")
.bss : {
__bss_start__ = .;
*(.bss)
*(.bss.*)
*(COMMON)
. = ALIGN(4);
__bss_end__ = .;
} >ram AT>ram :bss
ASSERT(__bss_end__ == ADDR(.bss) + SIZEOF(.bss), "BSS boundary excludes globals")
.commonarea (NOLOAD) : {
*(.commonarea)
} >commonarea
}