Files
proxmark3/fpga/common/hi_sniffer.v
T

85 lines
2.2 KiB
Verilog

//-----------------------------------------------------------------------------
// Copyright (C) Proxmark3 contributors. See AUTHORS.md for details.
//
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
//
// See LICENSE.txt for the text of the license.
//-----------------------------------------------------------------------------
module hi_sniffer(
input ck_1356meg,
input [7:0] adc_d,
output ssp_din,
output reg ssp_frame,
output ssp_clk,
output adc_clk,
output pwr_lo,
output pwr_hi,
output pwr_oe1,
output pwr_oe2,
output pwr_oe3,
output pwr_oe4
);
// We are only snooping, all off.
assign pwr_hi = 1'b0;
assign pwr_lo = 1'b0;
assign pwr_oe1 = 1'b0;
assign pwr_oe2 = 1'b0;
assign pwr_oe3 = 1'b0;
assign pwr_oe4 = 1'b0;
//reg ssp_frame;
reg [7:0] adc_d_out = 8'd0;
reg [2:0] ssp_cnt = 3'd0;
assign adc_clk = ck_1356meg;
assign ssp_clk = ~ck_1356meg;
assign ssp_din = adc_d_out[0];
always @(posedge ssp_clk)
begin
ssp_cnt <= ssp_cnt + 1'b1;
`ifdef WITH_TIMODE
if(ssp_cnt[2:0] == 3'b111) // set frame pin to high for TI mode on the last bit of the frame
begin
ssp_frame <= 1'b1;
end
`endif
if(ssp_cnt[2:0] == 3'b000) // set frame length
begin
adc_d_out[7:0] <= adc_d;
`ifdef WITH_TIMODE
ssp_frame <= 1'b0; // In TI mode, pull the frame signal low here—at the rising edge of the first bit (marking the end of the last bit).
`else
ssp_frame <= 1'b1; // In SSP mode, pull the frame signal high here.
`endif
end
else
begin
// shift value right one bit
adc_d_out[7:0] <= {1'b0, adc_d_out[7:1]};
`ifndef WITH_TIMODE
ssp_frame <= 1'b0; // In SSP mode, pull the frame signal low here.
`endif
end
end
endmodule